Simple test of battery drain during sleep

April 19, 2023

// derived from Adafruit Feather9x_TX

#include <SPI.h>
#include <RH_RF95.h>
#include <ArduinoLowPower.h>

// Feather M0 w/Radio
#define RFM95_CS      8
#define RFM95_INT     3
#define RFM95_RST     4

#define RF95_FREQ 915.0

RH_RF95 rf95(RFM95_CS, RFM95_INT);

void setup() 
{
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, HIGH); // Show we're awake

  pinMode(RFM95_RST, OUTPUT);
  digitalWrite(RFM95_RST, HIGH);

  Serial.begin(115200);

  delay(1000);

#if 0
  while (!Serial) {
    delay(1);
  }
#endif

  delay(100);

  Serial.println("Feather LoRa sleep Test!");

  // manual reset
  digitalWrite(RFM95_RST, LOW);
  delay(10);
  digitalWrite(RFM95_RST, HIGH);
  delay(10);

  while (!rf95.init()) {
    Serial.println("LoRa radio init failed");
    Serial.println("Uncomment '#define SERIAL_DEBUG' in RH_RF95.cpp for detailed debug info");
    while (1);
  }
  Serial.println("LoRa radio init OK!");

  // Defaults after init are 434.0MHz, modulation GFSK_Rb250Fd250, +13dbM
  if (!rf95.setFrequency(RF95_FREQ)) {
    Serial.println("setFrequency failed");
    while (1);
  }
  Serial.print("Set Freq to: "); Serial.println(RF95_FREQ);
  
  // Defaults after init are 434.0MHz, 13dBm, Bw = 125 kHz, Cr = 4/5, Sf = 128chips/symbol, CRC on

  // The default transmitter power is 13dBm, using PA_BOOST.
  // If you are using RFM95/96/97/98 modules which uses the PA_BOOST transmitter pin, then 
  // you can set transmitter powers from 5 to 23 dBm:
  rf95.setTxPower(23, false);

  delay(1000);

  Serial.println("before radio sleep");
  if (!rf95.sleep()) {
    Serial.println("radio sleep failed");
  }
  Serial.println("after radio sleep");

  delay(1000);
}

void loop()
{
  digitalWrite(LED_BUILTIN, LOW); // Show we're asleep
  delay(200);

  LowPower.deepSleep(10000);

#if defined(USBCON) && !defined(USE_TINYUSB)
  delay(100);
  USBDevice.attach();
  delay(100);
#endif

  digitalWrite(LED_BUILTIN, HIGH); // Show we're awake again
  delay(200);
}